DIST wkhtmltopdf-0.13.tar.gz 2434291 BLAKE2B ff2e37eed492c6a0fc49dced5979477ab1566d1590f0f852affc9926785e358bb09be8f40aeb1d28d08a9d8ea8492e9a8a6ae53edacff429bf8612bc497f5145 SHA512 4ab82238b66093874042561d2bf5db51579fd8200cce862a07e50705d012abb0ca051a5350ff04d7e0704adce19b945afa14a89880e8bbbd955d7ec1c46a8485

EBUILD wkhtmltopdf-0.13.ebuild 894 BLAKE2B 9fb89715477e0fc29ef9a8043a5a330c133c4cb3820a02de0a89f34df189b0eff715adac588fbb981cb9affaf89cc6a9871c2870f9429a9c67cf17a16fcd89fd SHA512 2cf388f46e5f220b7498bc007240c3735ff094b069200fac34a0c1c892a0faf62bf008cc800b536330948518273a817ba741f20e4015fd8b16cb3c352e8ebb9f

# Copyright 1999-2018 Gentoo Foundation

# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit qmake-utils

DESCRIPTION="Convert html to pdf (and various image formats) using webkit"

HOMEPAGE="https://wkhtmltopdf.org/ https://github.com/wkhtmltopdf/wkhtmltopdf/"

SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-3"

SLOT="0"

KEYWORDS="~amd64 ~x86"

IUSE="examples"

RDEPEND="

	dev-qt/qtcore:5

	dev-qt/qtgui:5

	dev-qt/qtnetwork:5[ssl]

	dev-qt/qtprintsupport:5

	dev-qt/qtsvg:5

	dev-qt/qtwebkit:5[printsupport]

	dev-qt/qtwidgets:5

"

DEPEND="${RDEPEND}

	dev-qt/qtxmlpatterns:5

"

src_prepare() {

	default

	sed -i "s:\(INSTALLBASE/\)lib:\1$(get_libdir):" src/lib/lib.pro || die

}

src_configure() {

	eqmake5 INSTALLBASE=/usr

}

src_install() {

	emake INSTALL_ROOT="${D}" install

	use examples && dodoc -r examples

	einstalldocs

}