diff --git a/games-rpg/pcgen/pcgen-6.08.00_rc8.ebuild b/games-rpg/pcgen/pcgen-6.08.00_rc8.ebuild
new file mode 100644
index 0000000000000000000000000000000000000000..f8c151baa0505fe17507c60a8c184c59067ea16c
--- /dev/null
+++ b/games-rpg/pcgen/pcgen-6.08.00_rc8.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop edos2unix
+
+MY_PV=${PV/_rc/RC}
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="D&D character generator"
+HOMEPAGE="http://pcgen.org/"
+SRC_URI="https://github.com/PCGen/pcgen/releases/download/${MY_PV}/${MY_P}-full.zip"
+S="${WORKDIR}/${PN}"
+
+LICENSE="LGPL-2.1 OGL-1.0a"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND=">=virtual/jre-11:*"
+BDEPEND="app-arch/unzip"
+
+src_prepare() {
+	default
+
+	edos2unix ${PN}.sh
+	sed "/^cd /c\\cd \"${EPREFIX}/opt/${PN}\" || exit 1" ${PN}.sh > "${T}"/${PN} || die
+
+	rm -r LICENSE docs/{doc_tools,pngcrush_logs.txt} ${PN}.{exe,sh} || die
+}
+
+src_install() {
+	dobin "${T}"/${PN}
+
+	insinto /opt/${PN}
+	doins -r .
+
+	newicon system/sponsors/pcgen/pcgen_128x128.png ${PN}.png
+	make_desktop_entry ${PN} PCGen
+}