# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

inherit eutils gnome2-utils systemd unpacker

# Major version
MV=${PV/\.*}
MY_PN=${PN}${MV}
DESCRIPTION="All-In-One Solution for Remote Access and Support over the Internet"
HOMEPAGE="https://www.teamviewer.com"
SRC_URI="https://download.teamviewer.com/download/version_${MV}x/${PN}_${PV}_i386.deb"

LICENSE="TeamViewer"
SLOT=${MV}
KEYWORDS="-* ~amd64 ~x86"

RESTRICT="bindist mirror"

RDEPEND="
	app-emulation/wine[abi_x86_32(-)]
	dev-qt/qtcore:4[abi_x86_32(-)]
	dev-qt/qtgui:4[abi_x86_32(-)]
	dev-qt/qtwebkit:4[abi_x86_32(-)]
	media-libs/alsa-lib[abi_x86_32(-)]
	x11-libs/libICE[abi_x86_32(-)]
	x11-libs/libSM[abi_x86_32(-)]
	x11-libs/libX11[abi_x86_32(-)]
	x11-libs/libXau[abi_x86_32(-)]
	x11-libs/libXdamage[abi_x86_32(-)]
	x11-libs/libXdmcp[abi_x86_32(-)]
	x11-libs/libXext[abi_x86_32(-)]
	x11-libs/libXfixes[abi_x86_32(-)]
	x11-libs/libXrandr[abi_x86_32(-)]
	x11-libs/libXtst[abi_x86_32(-)]"

QA_PREBUILT="opt/teamviewer${MV}/*"

S=${WORKDIR}/opt/teamviewer/tv_bin

src_prepare() {
	sed \
		-e "s/@TVV@/${MV}/g" \
		"${FILESDIR}"/${PN}d.init > "${T}"/init || die
	sed \
		-e "s/@TVV@/${MV}/g" \
		"${FILESDIR}"/${PN}d.conf > "${T}"/conf || die
}

src_install () {
	local destdir="/opt/${MY_PN}"

	# install wine prefix skeleton and reg keys
	insinto "${destdir}/wine/drive_c/"
	doins -r wine/drive_c/TeamViewer/
	# fix permissions
	fperms 755 ${destdir}/wine/drive_c/TeamViewer/TeamViewer.exe

	# install wine wrapper
	exeinto "/opt/bin"
	newexe "${FILESDIR}/${PN}.sh" "${MY_PN}"

	# install teamviewer linux binaries
	exeinto "${destdir}/tv_bin"
	doexe TeamViewer_Desktop TVGuiDelegate TVGuiSlave.32
	use amd64 && doexe TVGuiSlave.64

	# install daemon binary and scripts
	exeinto "${destdir}/tv_bin"
	doexe ${PN}d
	newinitd "${T}"/init ${PN}d${MV}
	newconfd "${T}"/conf ${PN}d${MV}
	systemd_newunit script/${PN}d.service ${PN}d${MV}.service

	# set up logdir
	keepdir /var/log/${MY_PN}
	dosym /var/log/${MY_PN} /opt/${MY_PN}/logfiles

	# set up config dir
	keepdir /etc/${MY_PN}
	dosym /etc/${MY_PN} /opt/${MY_PN}/config

	newicon -s 48 desktop/${PN}.png ${MY_PN}.png
	#dodoc ../doc/linux_FAQ_{EN,DE}.txt
	make_desktop_entry ${MY_PN} "TeamViewer ${MV}" ${MY_PN}
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update

	ewarn "STARTUP NOTICE:"
	elog "You cannot start the daemon via \"teamviewer --daemon start\"."
	elog "Instead use the provided gentoo initscript:"
	elog "  /etc/init.d/${PN}d${MV} start"
	elog
	elog "Logs are written to \"/var/log/teamviewer${MV}\""
}

pkg_postrm() {
	gnome2_icon_cache_update
}